[Overview][Constants][Types][Classes][Procedures and functions][Index] | Reference for unit 'ComCtrls' (#lcl)

# TToolButtonStyle

TToolButtonStyle - enumerated type that determines the style of the tool buttons.

## Declaration

Source position: comctrls.pp line 1494

`type TToolButtonStyle = (`
`tbsButton,`
`tbsCheck,`
`tbsDropDown,`
`tbsSeparator,`
`tbsDivider`
`);`

## Description

These are the possible values of Style:

- tbsButton - The button appears and functions like a normal button.
- tbsCheck - Clicking the button toggles the Down property. Once selected, the button remains selected until clicked again.
- tbsDivider - The button appears as a vertical line on the toolbar (used to separate other controls).
- tbsDropDown - The button displays a downwards-pointing arrow (suitable for accessing a drop-down menu).
- tbsSeparator - The button appears as an empty space on the toolbar (used to separate other controls).

## See also

#LCL.ComCtrls.TToolButton |  | TToolButton is a button control in a TToolBar object.

## Example

    { To use this example, create a new application and add the example code
      to the unit. Remember to add the ComCtls unit in the uses clause. }

    procedure AddButtons(ToolBar: TToolBar; const ButtonCaptions: array of String);
    var
      i: integer;
    begin
      for i := 0 to High(ButtonCaptions) do
      begin
        with TToolButton.Create(ToolBar) do
        begin
          Parent := ToolBar;
          Caption := ButtonCaptions[i];
          if (ButtonCaptions[i] = '|') then
            Style := tbsSeparator
          else
            Style := tbsButton;
          AutoSize := True;
        end;
      end;
    end;

    procedure TForm1.FormCreate(Sender: TObject);
    var
      ToolBar: TToolBar;
    begin
      ToolBar := TToolBar.Create(Self);
      ToolBar.Parent := Self;
      ShowMessage(IntToStr(ToolBar.ButtonCount));
      AddButtons(ToolBar, ['New', 'Save', '|', 'Cut', 'Copy', 'Paste']);
      ToolBar.ShowCaptions := True;
      ToolBar.Height := 40;
      ToolBar.ButtonWidth := 75;
      ShowMessage(IntToStr(ToolBar.ButtonCount));
    end;

The latest version of this document can be found at lazarus-ccr.sourceforge.net .